# $Id: PKGBUILD 105694 2014-02-14 06:29:13Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>

pkgname=pidgin-lwqq
pkgver=0.2c.20140214
_commit=de349f7a2d6b1728f4f03e374dd3bc000f4b1248
pkgrel=1
pkgdesc="A pidgin plugin based on lwqq, a excellent safe useful library for webqq protocol"
arch=('i686' 'x86_64' 'mips64el')
url="https://github.com/xiehuc/pidgin-lwqq"
license=('GPL3')
depends=('libpurple' 'curl' 'hicolor-icon-theme' 'gtk-update-icon-cache' 'libev' 'js185')
optdepends=('pidgin: Multi-protocol instant messaging client'
            'telepathy-haze: Empathy plugin support')
makedepends=('git' 'cmake')
install=$pkgname.install
options=(debug)
source=("git://github.com/xiehuc/pidgin-lwqq.git#commit=$_commit"
#source=("git://github.com/xiehuc/pidgin-lwqq.git#tag=$pkgver"
        "git://github.com/xiehuc/lwqq.git")

prepare() {
  cd $pkgname
  git submodule init
  git config submodule."liblwqq".url "$srcdir/lwqq"
  git submodule update
}

build() {
  cd $pkgname
  
  #Disable SSL as per upstream suggests
  cmake -DCMAKE_INSTALL_PREFIX=/usr -DSSL=Off .
  make
}

package() {
  cd $pkgname
  make DESTDIR="${pkgdir}" install
}

sha512sums=('SKIP'
            'SKIP')