# Maintainer: Peter Lewis <plewis@aur.archlinux.org>
# Contributor: Sebastian Köhler <sebkoehler@whoami.org.uk>

# This must be built against the version of dovecot being used,
# else mail delivery will fail.
# Specify the version of dovecot to be used here:
_dcpkgver=2.0.15
# Make sure to bump pkgrel if changing this.

pkgname=pigeonhole
pkgver=0.2.4
pkgrel=2
pkgdesc="Fully rewritten Sieve implementation for Dovecot v2.0"
arch=('i686' 'x86_64' 'mips64el')
url="http://pigeonhole.dovecot.org/"
license=('LGPL')
depends=('dovecot='$_dcpkgver)
makedepends=()
conflicts=('dovecot-sieve' 'pigeonhole-hg')
source=("http://www.rename-it.nl/dovecot/2.0/dovecot-2.0-$pkgname-$pkgver.tar.gz"
	"dovecot.conf")
options=('!libtool')
md5sums=('11d396b901db774799d07db6e4dd805b'
         '564b771c339f69a477c06babf53e11c2')

build() {
  cd "$srcdir/dovecot-2.0-$pkgname-$pkgver"

  ./configure --prefix=/usr --with-dovecot=/usr/lib/dovecot
  make
}

package() {
  cd "$srcdir/dovecot-2.0-$pkgname-$pkgver"
  
  make DESTDIR="$pkgdir/" install

  install -m 644 -D "$srcdir/dovecot.conf" "$pkgdir/etc/ld.so.conf.d/dovecot.conf"
}