# $Id: PKGBUILD 68038 2012-03-17 08:29:09Z bpiotrowski $
# Maintainer:  Bartłomiej Piotrowski
# Contributor: Laszlo Papp <djszapi2@gmail.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=pigz
pkgver=2.2.4
pkgrel=1
pkgdesc="Parallel implementation of the gzip file compressor"
arch=('i686' 'x86_64')
url="http://www.zlib.net/pigz/"
license=('custom')
depends=('zlib')
source=(http://www.zlib.net/$pkgname/$pkgname-$pkgver.tar.gz)
md5sums=('9df2a3c742524446fa4e797c17e8fd85')

build() {
  cd "${srcdir}/$pkgname-$pkgver"
  make
}

package() {
  cd "${srcdir}/$pkgname-$pkgver"

  install -Dm755 "${srcdir}"/${pkgname}-$pkgver/${pkgname} \
    "${pkgdir}"/usr/bin/${pkgname} 

  pushd "${pkgdir}"/usr/bin
    ln -s pigz unpigz 
  popd

  install -Dm644 "${srcdir}"/${pkgname}-$pkgver/${pkgname}.1 \
    "${pkgdir}"/usr/share/man/man1/${pkgname}.1
  install -Dm644 "${srcdir}"/${pkgname}-$pkgver/${pkgname}.pdf \
    "${pkgdir}"/usr/share/doc/${pkgname}/${pkgname}.pdf
  install -Dm644 "${srcdir}"/${pkgname}-$pkgver/README \
    "${pkgdir}"/usr/share/licenses/${pkgname}/README
}