# $Id: PKGBUILD 96184 2013-08-21 12:27:48Z spupykin $
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Alexander Fehr <pizzapunk@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=poedit
pkgver=1.5.7
pkgrel=4
pkgdesc="Cross-platform gettext catalogs (.po files) editor"
arch=('i686' 'x86_64')
url="http://www.poedit.net/"
license=('custom')
depends=('wxgtk2.9' 'gtkspell' 'db' 'hicolor-icon-theme' 'gettext')
makedepends=('pkgconfig' 'boost')
install=poedit.install
source=(http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz)
md5sums=('f5b53ec66a606f088b0aa388595ea5f9')

build() {
    cd ${srcdir}/${pkgname}-${pkgver}
    export WX_CONFIG_PATH=/usr/bin/wx-config-2.9
    ./configure --prefix=/usr
    make
}

package() {
    cd ${srcdir}/${pkgname}-${pkgver}
    make DESTDIR=${pkgdir} install
    install -D -m644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}