# $Id: PKGBUILD 72449 2012-06-14 17:35:54Z ttopper $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
# Contributor: Alois Nespor <alois.nespor@gmail.com>
# Contributor:  JerichoKru   <jerichokru(AT)htomail.com>

pkgname=pragha
pkgver=1.0.2
pkgrel=2
pkgdesc="A lightweight GTK+ music manager - fork of Consonance Music Manager."
arch=('i686' 'x86_64')
url="http://pragha.wikispaces.com/"
license=('GPL3')
depends=('libnotify' 'libcdio' 'gstreamer0.10-base'
         'taglib' 'hicolor-icon-theme'  'gtk2'
         'dbus-glib' 'sqlite' 'desktop-file-utils'
         'libclastfm')
optdepends=('notification-daemon: OSD notification')
replaces=('dissonance')
install=pragha.install
source=("https://github.com/downloads/matiasdelellis/pragha/$pkgname-$pkgver.tar.bz2")
sha1sums=('297381d068860c22649ca29ae2281f9f6e33c000')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  LIBS+="-ldbus-glib-1"  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
	
  install -m 644 "data/$pkgname.desktop" "$pkgdir/usr/share/applications"
  install -d "$pkgdir/usr/share/pixmaps"
  install -m 644 "data/$pkgname.png" "$pkgdir/usr/share/pixmaps/"
  install -m 644 "data/$pkgname.1" "$pkgdir/usr/share/man/man1/"

}

# vim:ts=2:sw=2:expandtab