# $Id: PKGBUILD 53500 2011-08-04 16:53:43Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
pkgname=python2-pyopencl
pkgver=2011.1.2
pkgrel=1
pkgdesc="A complete, object-oriented language binding of OpenCL to Python"
arch=('i686' 'x86_64' 'mips64el')
url="http://mathema.tician.de/software/pyopencl"
license=('custom')
depends=('python2' 'python2-numpy' 'python-mako' 'libcl' 'opencl-headers')
makedepends=('ctags' 'python2-distribute')
provides=('pyopencl=${pkgver}')
replaces=('pyopencl')
conflicts=('pyopencl')
source=("http://pypi.python.org/packages/source/p/pyopencl/pyopencl-${pkgver}.tar.gz"
        'LICENSE.txt')
sha1sums=('5ecc476b86317ed065c75c1d8efb2a53d1d8f075'
          '2e6966b3d9b15603ce2c3ff79eeadd63c5d066b7')

build() {
   cd "${srcdir}/pyopencl-${pkgver}"
   python2 ./configure.py --cl-inc-dir=/usr/include \
		                    --cl-lib-dir=/usr/lib \
		                    --cl-libname=OpenCL
   python2 setup.py build
}

package() {
   cd "${srcdir}/pyopencl-${pkgver}"
   python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build

   install -D -m644 ../LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}