# $Id: PKGBUILD 96151 2013-08-20 11:37:41Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Giovanni Scafora <linuxmania@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=qcad
pkgver=3.2.0.0
pkgrel=2
pkgdesc="A 2D CAD package based upon Qt"
arch=('i686' 'x86_64')
url="http://www.ribbonsoft.com/qcad.html"
license=('GPL3')
depends=('qtwebkit')
makedepends=('glu')
options=(libtool)
source=($pkgname-$pkgver.tar.gz::https://github.com/qcad/qcad/archive/v${pkgver}.tar.gz
        QCad.desktop)
md5sums=('6dd9c47742a0193a739d390e81ca67d0'
         '35100eaedbdf6625f6e6a09b177854cd')

prepare() {
  cd ${srcdir}/qcad-$pkgver
  sed -i '1,1i#include <unistd.h>' src/core/{RLocalPeer,RS}.cpp
  sed -i '1,1i#include <sys/sysinfo.h>' src/core/{RScriptHandler,RS}.cpp
  (cd src/3rdparty &&
    cp -a qt-labs-qtscriptgenerator-4.8.4 qt-labs-qtscriptgenerator-4.8.5)
  (cd src/3rdparty/qt-labs-qtscriptgenerator-4.8.5 &&
    mv qt-labs-qtscriptgenerator-4.8.4.pro qt-labs-qtscriptgenerator-4.8.5.pro)
}

build() {
  cd ${srcdir}/qcad-$pkgver
  qmake-qt4 -r
  make all -j1
}

package() {
  cd ${srcdir}/qcad-$pkgver

  # remove project files
  find . \( -name '*.pri' -or -name '.pro' -or -name '*.ts' \) -delete
  find . \( -name 'Makefile' -name '.gitignore' \) -delete

  install -dm755 ${pkgdir}/usr/share/{qcad,pixmaps,applications}
  cp -r examples fonts libraries patterns plugins scripts ts ${pkgdir}/usr/share/qcad
  cp debug/* ${pkgdir}/usr/share/qcad

  install -m755 readme.txt ${pkgdir}/usr/share/qcad/readme.txt

  # qtwebkit
  ln -sf /usr/lib/qt4/plugins/designer/libqwebview.so ${pkgdir}/usr/share/qcad/plugins/designer/libqwebview.so
  # qt
  for sofiles in /usr/lib/qt4/plugins/imageformats/*.so
  do
    ln -sf ${sofiles} ${pkgdir}/usr/share/qcad/plugins/imageformats/${sofiles##/*/}
  done
  for sofiles in /usr/lib/qt4/plugins/sqldrivers/*.so
  do
    ln -sf ${sofiles} ${pkgdir}/usr/share/qcad/plugins/sqldrivers/${sofiles##/*/}
  done

  install -Dm644 scripts/qcad_icon.png ${pkgdir}/usr/share/pixmaps/qcad_icon.png
  install -Dm644 $srcdir/QCad.desktop ${pkgdir}/usr/share/applications/QCad.desktop

  install -dm0755 $pkgdir/usr/bin
  echo -e '#!/bin/sh\ncd /usr/share/qcad\nLD_LIBRARY_PATH=`pwd`:$LD_LIBRARY_PATH exec ./qcad-bin' >$pkgdir/usr/bin/qcad
  chmod 0755 $pkgdir/usr/bin/qcad
}