# $Id: PKGBUILD 61091 2011-12-21 20:52:19Z andrea $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Matthias Maennich <arch@maennich.net>
# Contributor: <boenki@gmx.de>

pkgname=qlandkartegt
pkgver=1.3.1
pkgrel=2
pkgdesc="Use your GPS with Linux"
arch=('i686' 'x86_64')
url="http://www.qlandkarte.org/"
license=('GPL')
depends=('gdal' 'gpsd' 'libdmtx' 'libexif' 'libmysqlclient' 'mesa' 'postgresql-libs'
         'qt' 'shared-mime-info' 'qtwebkit')
makedepends=('cmake' 'garmindev')
optdepends=('garmindev: to connect garmin devices')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz
        $pkgname-mimetypes.xml)
sha256sums=('77a387856e2d41f9ea69f750cbac9bb49fa249d65bdef5e319bfa6f7c9f84121'
            'e8d33948831f8a66edd752c71c653085d6c4d9f1969e70dd8c40b9c7ca37fba0')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  cd ${srcdir}
  mkdir build
  cd build

  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package(){
  cd ${srcdir}/build

  make DESTDIR=${pkgdir} install

  install -D -m644 ${srcdir}/$pkgname-mimetypes.xml \
    ${pkgdir}/usr/share/mime/packages/$pkgname-mimetypes.xml
}