# $Id: PKGBUILD 106093 2014-02-22 12:16:01Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Matthias Maennich <arch@maennich.net>
# Contributor: <boenki@gmx.de>

pkgname=qlandkartegt
pkgver=1.7.6
pkgrel=1
pkgdesc="Use your GPS with Linux"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.qlandkarte.org/"
license=('GPL')
depends=('gdal' 'gpsd' 'libdmtx' 'libexif' 'libmariadbclient' 'glu' 'postgresql-libs'
         'shared-mime-info' 'qtwebkit')
makedepends=('cmake' 'garmindev' 'mesa')
optdepends=('garmindev: to connect garmin devices')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz
        $pkgname-mimetypes.xml)
sha256sums=('ff1e352d07fd136e75a80035d888efe095f1f44ca15d46262169e98e5a14e1c3'
            'e8d33948831f8a66edd752c71c653085d6c4d9f1969e70dd8c40b9c7ca37fba0')

build() {
  cd "${srcdir}"
  mkdir build
  cd build

  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package(){
  cd "${srcdir}/build"

  make DESTDIR="${pkgdir}" install

  install -D -m644 "${srcdir}/$pkgname-mimetypes.xml" \
    "${pkgdir}/usr/share/mime/packages/$pkgname-mimetypes.xml"
}