# $Id: PKGBUILD 98046 2013-10-04 15:27:57Z bgyorgy $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: cdhotfire <cdhotfire@gmail.com>

pkgname=rawstudio
pkgver=2.0
pkgrel=9
pkgdesc="An open source raw-image converter written in GTK+"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://rawstudio.org/"
depends=('gconf' 'lcms' 'exiv2' 'fftw' 'lensfun' 'flickcurl' 'sqlite'
	 'libgphoto2' 'gtk-engines' 'desktop-file-utils')
install=${pkgname}.install
options=('!libtool')
source=(http://rawstudio.org/files/release/${pkgname}-${pkgver}.tar.gz
	libpng15.patch)
md5sums=('b2f86b8ca6b83ad954e3104c4cb89e9b'
         '2f8b7acbe10d8096ce613cbea7986fd3')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 <$srcdir/libpng15.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  export LDFLAGS="$LDFLAGS `pkg-config --libs gthread-2.0`"
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make prefix="${pkgdir}/usr" install
  mkdir $pkgdir/usr/lib/rawstudio
  mv $pkgdir/usr/share/rawstudio/plugins $pkgdir/usr/lib/rawstudio
  ln -s ../../lib/rawstudio/plugins $pkgdir/usr/share/rawstudio/plugins
}