# $Id: PKGBUILD 82318 2013-01-14 22:03:09Z andrea $
# Maintainer: Peter Lewis <plewis@aur.archlinux.org>
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Panagiotis Papadopoulos <pano_90 AT gmx DOT net>

pkgname=rekonq
pkgver=2.0
pkgrel=2
pkgdesc='A WebKit based web browser for KDE'
arch=('i686' 'x86_64')
url='http://rekonq.kde.org/'
license=('GPL')
depends=('kdebase-keditbookmarks' 'qoauth')
makedepends=('cmake' 'automoc4')
optdepends=('qca-ossl: to use the sync handler')
install=${pkgname}.install
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        'fix-google-sync.patch')
sha256sums=('380aa337b561ee0c5eb1aa8401f7bd8d98a2b18e645e92f3387baae06d501d84'
            '7360746d3668c1353e0b30351d33014c41d3171d64a43fed5178207883291001')

build(){
  cd ${pkgname}-${pkgver}
  patch -p1 -i "${srcdir}"/fix-google-sync.patch
  cd ../

  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}