# $Id: PKGBUILD 73875 2012-07-16 07:53:58Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: JJDaNiMoTh <jjdanimoth.aur@gmail.com>
# Contributor: Tino Reichardt <milky-archlinux@mcmilk.de>

pkgname=sarg
pkgver=2.3.1
pkgrel=5
pkgdesc="Squid Analysis Report Generator"
arch=('i686' 'x86_64' 'mips64el')
url="http://sarg.sourceforge.net"
license=('GPL')
depends=('gd' 'libldap')
makedepends=('cmake')
backup=('etc/sarg/css.tpl'
	'etc/sarg/exclude_codes'
	'etc/sarg/sarg.conf'
	'etc/sarg/user_limit_block')
source=(http://downloads.sourceforge.net/sourceforge/sarg/$pkgname-$pkgver.tar.gz)
md5sums=('bf637b8a820b81e2c55e815934151b4d')

build() {
  cd ${srcdir}/$pkgname-$pkgver
  ./configure --prefix=/usr # po files workaround
  rm -f Makefile
  LDFLAGS=-lm cmake -DCMAKE_INSTALL_PREFIX=/usr -DSYSCONFDIR=/etc/sarg -DMANDIR=/usr/share/man/man1 .
  make
}

package() {
  cd ${srcdir}/$pkgname-$pkgver
  mkdir -p $pkgdir/usr/share/sarg $pkgdir/etc
  make DESTDIR="$pkgdir" install
  make -C po DESTDIR="$pkgdir" install
  cp -a sarg-php ${pkgdir}/usr/share/sarg/
  chmod -R o+r ${pkgdir}{/etc,/usr/share/sarg}
  chmod o+x ${pkgdir}/usr/share/sarg/sarg-php
  chmod -R o+x ${pkgdir}/usr/share/sarg/sarg-php/locale
}