# $Id: PKGBUILD 96421 2013-08-28 11:35:15Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Joeny Ang <ang(dot)joeny(at)gmail(dot)com>

pkgname=shotwell
pkgver=0.14.1
pkgrel=5
pkgdesc="A digital photo organizer designed for the GNOME desktop environment"
arch=('i686' 'x86_64')
url="http://yorba.org/shotwell/"
license=('LGPL2.1')
depends=('libgee06' 'webkitgtk' 'libgexiv2' 'libraw' 'rest'
	 'desktop-file-utils' 'dconf' 'hicolor-icon-theme' 'json-glib'
	 'gst-plugins-base' 'libgphoto2')
makedepends=('intltool' 'vala>=0.17.2' 'libunique3')
install=shotwell.install
source=("http://yorba.org/download/shotwell/stable/shotwell-$pkgver.tar.xz"
	"no-libexec.patch"
	"libraw-0.15.2.patch"
	"FS35899.patch::http://redmine.yorba.org/projects/shotwell/repository/revisions/4f635ba4236dbbb8cb3f8b7bdd201432961fb283/diff/src/AppDirs.vala?format=diff")
md5sums=('bb5783f9265e1ce2d4c9f354987c3ab1'
         'b4124e022c98b4382530e6fbcef965e2'
         '3ad21364f82229122f48452f5c74dfde'
         '9f9690f4b860f52ffd44f8ab6d4fd3b5')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 <$srcdir/no-libexec.patch
  patch -Rp1 <$srcdir/libraw-0.15.2.patch
  patch -p1 <$srcdir/FS35899.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
	--disable-schemas-compile \
	--disable-desktop-update \
	--disable-icon-update
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}