# $Id: PKGBUILD 84210 2013-02-13 18:46:24Z bpiotrowski $
# Maintainer:  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: IgnorantGuru http://igurublog.wordpress.com/contact-ignorantguru/
# Contributor: ridikulus_rat <the.ridikulus.rat@gmail.com>

pkgname=spacefm
pkgver=0.8.6
pkgrel=1
pkgdesc='Multi-panel tabbed file manager'
arch=('i686' 'x86_64' 'mips64el')
url='http://ignorantguru.github.com/spacefm/'
license=('GPL3')
install=$pkgname.install
depends=('gtk3' 'shared-mime-info' 'desktop-file-utils' 'startup-notification' 'udev')
makedepends=('intltool' 'gettext')
optdepends=('lsof: device processes'
			'eject: eject media'
            'wget: plugin download'
            'gksu: perform as root functionality'
            'udevil: mount as non-root user and mount networks'
            'udisks: mount as non-root user'
            'udisks2: mount as non-root user')
source=(https://raw.github.com/IgnorantGuru/$pkgname/master/packages/$pkgver/$pkgname-$pkgver.tar.xz)
sha256sums=('27f898d180c8a679568f0b40a05b470d728d38c892f4032654c4f696bab476e5')

build() {
	cd $srcdir/$pkgname-$pkgver
	./configure --prefix=/usr \
				--disable-pixmaps \
				--with-gtk3
	make
}

package() {
	cd $srcdir/$pkgname-$pkgver
	make DESTDIR=$pkgdir install
}