# $Id: PKGBUILD 55636 2011-09-17 00:06:15Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: DuGi <dugi@irc.pl>

pkgname=springlobby
pkgver=0.139
pkgrel=1
pkgdesc="A free cross-platform lobby client for the Spring RTS project."
arch=('i686' 'x86_64' 'mips64el')
url="http://springlobby.info/"
license=('GPL2')
depends=('wxgtk' 'curl' 'libtorrent-rasterbar' 'boost-libs')
optdepends=('sdl' 'sdl_sound' 'sdl_mixer') 
makedepends=('boost' 'asio' 'cmake')
source=(http://www.springlobby.info/tarballs/${pkgname}-${pkgver}.tar.bz2 
        springlobby.desktop
        springlobby.png)
md5sums=('48c572117338277068c67ec1ff7d514f'
         '45f8b59d033931d02e734fe3bd7777dd'
         '1f388187539aeb0358b51995e26ed890')

build() {
  cd $srcdir/${pkgname}-$pkgver

  export CXXFLAGS="${CXXFLAGS} -DBOOST_FILESYSTEM_VERSION=2"

  sed -i 's/boost_system-mt/boost_system/g' $srcdir/$pkgname-$pkgver/CMakeLists.txt

  cmake . \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DOPTION_SOUND=false
  make 
}

package() {
  cd $srcdir/${pkgname}-$pkgver

  make DESTDIR=$pkgdir install
  
  install -m755 -d $pkgdir/usr/share/applications
  install -m644 $srcdir/springlobby.desktop $pkgdir/usr/share/applications

  install -m755 -d -p $pkgdir/usr/share/pixmaps
  install -m644 $srcdir/springlobby.png $pkgdir/usr/share/pixmaps
}

# vim: sw=2:ts=2 et: