# $Id: PKGBUILD 67507 2012-03-12 21:46:37Z lcarlier $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: lowercase

pkgname=unace
pkgver=2.5
pkgrel=7
pkgdesc="An extraction tool for the proprietary ace archive format"
arch=('i686' 'x86_64')
url="http://www.winace.com/"
license=("custom")
depends=(ncurses)
install=unace.install
source=(http://ftp.debian.org/debian/pool/non-free/u/unace-nonfree/unace-nonfree_2.5.orig.tar.gz \
        01-makefiles.dpatch 04-64bit.dpatch)
md5sums=('59013e74e5ac2ee15c1e92026ec1e3cc' '6a1498f24d6430723acf556e0d1cc72b'\
         'c46de484cf5dc0e04c342062139a8aaf')
sha1sums=('f658f03aa6f663c1a90af85e3e8c6e7ef12adb42'
          '83b2b84223072b6f456d7255c80bec4e01572be0'
          'cccd98f1b99218ec69f27425b56b44d23c75eb1e')

build() {
  cd ${srcdir}/unace-$pkgver

  patch -p1 < ../01-makefiles.dpatch
  [ "$CARCH" = "x86_64" ] && (patch -p1 < ../04-64bit.dpatch)
  make
}

package() {
  cd ${srcdir}/unace-$pkgver

  install -D -m755 unace ${pkgdir}/usr/bin/unace
  install -D -m644 licence ${pkgdir}/usr/share/licenses/unace/license
}