# $Id: PKGBUILD 88423 2013-04-17 12:42:33Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: dorphell <dorphell@archlinux.org>

pkgname=xlockmore
pkgver=5.42
pkgrel=1
pkgdesc="screen saver / locker for the X Window System"
arch=(i686 x86_64)
license=('BSD')
depends=(freetype2 gtk2 libxpm lesstif pam libxmu glu)
optdepends=('fortune-mod')
makedepends=(mesa)
url="http://www.tux.org/~bagleyd/xlockmore.html"
options=('!makeflags')
source=(http://www.tux.org/~bagleyd/xlock/xlockmore-$pkgver/xlockmore-$pkgver.tar.bz2
	LICENSE)
md5sums=('de1dc31f686178703659fbb46d638518'
         'a64afab4283f53972a6702c2e59850d7')

build() {
  cd $srcdir/$pkgname-$pkgver
  ./configure --prefix=/usr --disable-setuid \
	      --enable-appdefaultdir=/usr/share/X11/app-defaults \
	      --enable-pam --with-gtk2 --without-esound --without-ftgl
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver

  make xapploaddir=$pkgdir/usr/share/X11/app-defaults \
       mandir=$pkgdir/usr/man/man1 \
       prefix=$pkgdir/usr install
  install -D -m644 ../LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
  mv $pkgdir/usr/man $pkgdir/usr/share/
}