# $Id: PKGBUILD 49967 2011-06-22 19:45:42Z vegai $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: shild <shildv@gmail.com>

pkgname=xmonad
pkgver=0.9.2
pkgrel=2.1
pkgdesc="A lightweight X11 tiled window manager written in Haskell"
arch=('i686' 'x86_64')
url="http://xmonad.org/"
license=('BSD')
depends=('ghc=7.0.3' 'gmp' 'haskell-x11=1.5.0.0' 'sh' 'haskell-mtl=2.0.1.0' 'haskell-utf8-string=0.3.6')
install='xmonad.install'
source=(http://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz
        xmonad.desktop xmonad.session xmonad.svg)

build() {
  cd $srcdir/$pkgname-$pkgver
  runhaskell Setup.lhs configure --ghc --enable-shared --enable-split-objs --prefix=/usr \
             --libsubdir=\$compiler/site-local/\$pkgid
  runhaskell Setup build
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
  cd $srcdir/$pkgname-$pkgver
  install -D -m744 register.sh $pkgdir/usr/share/haskell/$pkgname/register.sh
  install -m744 unregister.sh $pkgdir/usr/share/haskell/$pkgname/unregister.sh
  runhaskell Setup.lhs copy --destdir=$pkgdir
#  runhaskell util/GenerateManpage.hs

  install -D -m644 man/xmonad.1 $pkgdir/usr/share/man/man1/xmonad.1

  install -D -m644 LICENSE $pkgdir/usr/share/licenses/xmonad/LICENSE

  install -D -m644 $srcdir/xmonad.desktop $pkgdir/usr/share/xsessions/xmonad.desktop
  install -D -m644 $srcdir/xmonad.session $pkgdir/usr/share/gnome-session/sessions/xmonad.session
  install -D -m644 $srcdir/xmonad.svg $pkgdir/usr/share/pixmaps/xmonad.svg
}
md5sums=('5a4117f798664d772d2a834ea6c90f1c'
         'f8e3d84a9f154d1b5d7fcffbc0a058c9'
         '9d1bc84a7f32897d32f3fc71ef76228e'
         '72bfa5e62e4e44fe7fa59b6a7593d993')