# $Id: PKGBUILD 70645 2012-05-13 19:04:54Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Robert Emil Berge <filoktetes@linuxophic.org>

pkgname=yaz
pkgver=4.2.33
pkgrel=1
pkgdesc="A toolkit supporting the development of Z39.50/SRW/SRU clients and servers"
arch=('i686' 'x86_64')
url="http://www.indexdata.dk/yaz"
license=('BSD')
depends=('openssl' 'libxslt' 'icu')
options=('!libtool')
source=("http://ftp.indexdata.dk/pub/$pkgname/$pkgname-$pkgver.tar.gz")
sha256sums=('77baecaa0b032c0155676e704d39b49415d4793ab65ad6c26e04f6dfb0be1276')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  ./configure --prefix=/usr \
              --enable-shared=yaz \
              --with-openssl=/usr
  make
}

package() {
  cd ${srcdir}/$pkgname-$pkgver

  make DESTDIR=${pkgdir} install

  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/$pkgname/LICENSE
}