# $Id: PKGBUILD 75255 2012-08-17 04:30:40Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Adrián Chaves Fernández (aka Gallaecio) <adriyetichaves@gmail.com>
# Contributor: Todd Partridge (aka Gen2ly) <toddrpartridge@gmail.com>

pkgname=zaz
pkgver=1.0.0
pkgrel=3
pkgdesc="Puzzle game where the player has to arrange balls in triplets."
arch=('i686' 'x86_64' 'mips64el')
url="http://sourceforge.net/projects/zaz/"
license=('GPL3' 'custom:CCBYSA')
depends=('ftgl' 'sdl' 'sdl_image' 'libvorbis' 'libtheora' 'desktop-file-utils')
source=(http://download.sourceforge.net/sourceforge/zaz/files/$pkgname-$pkgver.tar.bz2)
md5sums=('d92a043780d06c699da0ba04aab32a6b')
install=zaz.install

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr --disable-splash
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install

  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/LICENSE
  install -Dm644 data/copyright.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE_DATA
}