# $Id: PKGBUILD 199885 2013-11-18 07:11:38Z tpowa $
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>

pkgname=kbd
pkgver=2.0.1
pkgrel=1
pkgdesc="Keytable files and keyboard utilities"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.kbd-project.org"
license=('GPL')
depends=('glibc' 'pam')
makedepends=('check')
source=(ftp://ftp.altlinux.org/pub/people/legion/kbd/${pkgname}-${pkgver}.tar.gz
        'fix-dvorak-es.patch'
        'fix-euro2.patch')
provides=('vlock')
conflicts=('vlock')
replaces=('vlock')
md5sums=('cc0ee9f2537d8636cae85a8c6541ed2e'
         '998957c4f815347dcc874c4d7555dc66'
         'd869200acbc0aab6a9cafa43cb140d4e')

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}
  # rename keymap files with the same names
  # this is needed because when only name of keymap is specified
  # loadkeys loads the first keymap it can find, which is bad (see FS#13837)
  # this should be removed when upstream adopts the change
  mv data/keymaps/i386/qwertz/cz{,-qwertz}.map
  mv data/keymaps/i386/olpc/es{,-olpc}.map
  mv data/keymaps/i386/olpc/pt{,-olpc}.map
  mv data/keymaps/i386/dvorak/no{,-dvorak}.map
  mv data/keymaps/i386/fgGIod/trf{,-fgGIod}.map
  mv data/keymaps/i386/colemak/{en-latin9,colemak}.map
  # fix es-dvorak #33662
  patch -Np1 -i ../fix-dvorak-es.patch
  # fix euro2 #28213
  patch -Np1 -i ../fix-euro2.patch
}

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure --prefix=/usr --datadir=/usr/share/kbd --mandir=/usr/share/man
  make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes DESTDIR=${pkgdir} install
}