# $Id: PKGBUILD 175120 2013-01-14 07:38:18Z tpowa $
#
pkgname=xfsprogs
pkgver=3.1.10
pkgrel=1
pkgdesc="XFS filesystem utilities"
arch=('i686' 'x86_64' 'mips64el')
license=('LGPL')
url="http://oss.sgi.com/projects/xfs/"
groups=('base')
depends=('util-linux')
options=('!makeflags' '!libtool')
# We mirror the sources as upstream tends to move them once a new release is out
source=("ftp://ftp.archlinux.org/other/xfsprogs/${pkgname}-${pkgver}.tar.gz")
md5sums=('d6159f7a664d95b4c150d580399d4400')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  export OPTIMIZER="-march=${CARCH/_/-} -O1"
  [ "$CARCH" = "mips64el" ] && export OPTIMIZER="-mabi=n32 -march=mips3 -mtune=loongson2f -O1"
  export DEBUG=-DNDEBUG
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DIST_ROOT="${pkgdir}" install install-dev
  chown -R root $pkgdir
  chgrp -R root $pkgdir
  # add hack as we cannot set rootlibdir
  mv "${pkgdir}"/lib/libhandle.so* "${pkgdir}/usr/lib/"
  rm -rf "${pkgdir}/lib"
}