# Contributor: Vojtech Horky <vojta . horky at-symbol seznam . cz>

_pkgname=binutils
_target="mips64el-unknown-linux-gnu"
_sysroot="/usr/${_target}"

unset CFLAGS CXXFLAGS LDFLAGS

pkgname=${_target}-binutils
pkgver=2.22
pkgrel=1
pkgdesc="A set of programs to assemble and manipulate binary and object files for the MIPS architecture"
url="http://www.gnu.org/software/binutils/"
arch=('i686' 'x86_64')
license=('GPL')
depends=('zlib')
provices=("cross-${pkgname}")
source=("ftp://ftp.gnu.org/gnu/binutils/${_pkgname}-${pkgver}.tar.bz2")
md5sums=('ee0f10756c84979622b992a4a61ea3f5')

build() {
	cd ${srcdir}/${_pkgname}-${pkgver}

    CFLAGS=" -pipe "\
    CXXFLAGS=" -pipe "\
    ./configure --build=${CHOST} \
                --host=${CHOST} \
                --target=${_target} \
                --prefix=/usr \
                --disable-nls \
                --disable-multilib \
                --disable-werror \
                --enable-ld=yes \
                --enable-gold=no \
                --with-sysroot=${_sysroot}

	make 
}

package() {

	cd ${srcdir}/${_pkgname}-${pkgver}
	
	make DESTDIR=${pkgdir} install

    rm -r ${pkgdir}/usr/{lib,share}

# Create include dir so gcc-core doesn't complain
    mkdir -p ${pkgdir}${_sysroot}/usr/include
}