# $Id: PKGBUILD 197290 2013-10-25 01:17:05Z allan $
# Maintainer:
# Contributor: Thomas Baechler <thomas@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>

pkgname=a52dec
pkgver=0.7.4
pkgrel=8
pkgdesc="A free library for decoding ATSC A/52 streams"
url="http://liba52.sourceforge.net/"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL2')
depends=('glibc')
source=("http://liba52.sourceforge.net/files/${pkgname}-${pkgver}.tar.gz"
        'a52dec-0.7.4-build.patch'
	'configure.patch')
md5sums=('caa9f5bc44232dc8aeea773fea56be80'
         'fa16f224a7dceb7613824380abef0052'
         'ccaa978e70cc74b364486bd72fd38d1d')

prepare() {
  cd "${pkgname}-${pkgver}"
  patch -Np1 -i ../a52dec-0.7.4-build.patch
  sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' configure.in
  mv configure.in configure.ac
  ./bootstrap
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --enable-shared \
              --build=${CARCH} --host=${CARCH}
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -m644 liba52/a52_internal.h "${pkgdir}/usr/include/a52dec/"
}