# $Id: PKGBUILD 102234 2010-12-06 22:32:25Z ibiru $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Maël Lavault <moimael@neuf.fr>

pkgbase=abiword
pkgname=('abiword' 'abiword-plugins')
pkgver=2.8.6
pkgrel=4
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.abisource.com"
makedepends=('pkgconfig' 'asio' 'boost' 'fribidi' 'goffice' 'libwmf' 'wv' 'link-grammar' 'gtkmathview' 'aiksaurus' 'libxslt' 'enchant' 'libots' 'libwpg' 'librsvg' 'loudmouth' 'libsoup')
options=('!makeflags' '!libtool')
source=("http://www.abisource.com/downloads/${pkgbase}/${pkgver}/source/${pkgbase}-${pkgver}.tar.gz"
        compat_libwpg_0_9.patch)
sha1sums=('998f69d038000b3fc027d4259548f02d67c8d0df'
          'e5374f439e3d9b63a4bbd2cd39146c67cf1e85ea')

if [ "${CARCH}" = 'mips64el' ]; then
    
    ARCHFLAGS=""
    for opt in ${CFLAGS}; do
        case ${opt} in
            -O?) ARCHFLAGS+="-O1 " ;;
            *) ARCHFLAGS+="${opt} " ;;
        esac
    done
    CFLAGS=${ARCHFLAGS}

    ARCHFLAGS=""
    for opt in ${CXXFLAGS}; do
        case ${opt} in
            -O?) ARCHFLAGS+="-O1 " ;;
            *) ARCHFLAGS+="${opt} " ;;
        esac
    done
    CXXFLAGS=${ARCHFLAGS}

    unset ARCHFLAGS

    echo CFLAGS  : ${CFLAGS}
    echo CXXFLAGS: ${CXXFLAGS}
fi


build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"

  patch -Np1 -i "${srcdir}/compat_libwpg_0_9.patch"
  libtoolize --force
  autoreconf

  ./configure --prefix=/usr --enable-clipart --enable-templates --enable-collab-backend-xmpp --enable-collab-backend-tcp --enable-collab-backend-service --disable-collab-backend-sugar --enable-plugins --without-gnomevfs --with-gio --with-goffice --disable-static --with-psiconv-config=/nothere
  make
}

package_abiword() {
  pkgdesc="A fully-featured word processor"
  depends=('fribidi' 'wv' 'goffice' 'librsvg' 'enchant')
  optdepends=('abiword-plugins')
  conflicts=("abiword-plugins<${pkgver}-${pkgrel}")

  cd "${srcdir}/${pkgbase}-${pkgver}"
  sed -i plugins/Makefile \
      -e 's/ collab / /' \
      -e 's/ wpg / /' \
      -e 's/ wmf / /' \
      -e 's/ grammar / /' \
      -e 's/ mathview / /' \
      -e 's/ aiksaurus / /' \
      -e 's/ latex / /' \
      -e 's/ ots / /' \
      -e 's/ wordperfect / /'
  make DESTDIR="${pkgdir}" install
}

package_abiword-plugins() {
  pkgdesc="Additional plugins for Abiword"
  depends=("abiword=${pkgver}-${pkgrel}" 'loudmouth' 'libwpg' 'libwmf' 'link-grammar' 'gtkmathview' 'aiksaurus' 'libxslt' 'libsoup' 'libots')

  cd "${srcdir}/${pkgbase}-${pkgver}/plugins"
  for dir in collab wpg wmf grammar mathview aiksaurus latex ots wordperfect; do
    make -C ${dir} DESTDIR="${pkgdir}" install
  done
}