# $Id: PKGBUILD 124404 2011-05-20 15:01:13Z bisson $
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Maintainer: Gaetan Bisson <bisson@archlinux.org>

pkgname=audacious
pkgver=2.5.1
pkgrel=1
pkgdesc='Lightweight, GTK2-based advanced audio player focused on audio quality'
arch=('i686' 'x86_64' 'mips64el')
url='http://audacious-media-player.org/'
license=('GPL3')
depends=('gtk2' 'libmcs' 'dbus-glib' 'libguess' 'audacious-plugins' 'desktop-file-utils' 'hicolor-icon-theme')
optdepends=('unzip: zipped skins support')
source=("http://distfiles.atheme.org/$pkgname-$pkgver.tgz")
sha1sums=('886e1cde03069b3dee15a6df04e3e8f5934018f1')

provides=('audacious-player')
replaces=('audacious-player')
install=install

build() {
	cd "$srcdir/$pkgname-$pkgver"
	[[ $CARCH == x86_64 ]] && extraopts='' || extraopts='--disable-sse2'
	./configure --prefix=/usr $extraopts
	make
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	make DESTDIR="$pkgdir" install
}