# $Id: PKGBUILD 146761 2012-01-17 05:11:17Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=audacity
pkgver=1.3.14
pkgrel=2
pkgdesc="A program that lets you manipulate digital audio waveforms"
arch=(mips64el)
url="http://audacity.sourceforge.net/"
license=('GPL')
depends=('libmad' 'libid3tag' 'wxgtk' 'lame' 'hicolor-icon-theme'
	 'desktop-file-utils' 'jack' 'soundtouch' 'ffmpeg')
options=('!makeflags')
install=audacity.install
source=(http://audacity.googlecode.com/files/${pkgname}-minsrc-${pkgver}-beta.tar.bz2 \
        audacity-1.3.13-ffmpeg.patch)
sha1sums=('a0fb22a0cfbb8a72abac8bbc01b3ad8b0bb7e11e'
          '67f209d362ece6961b154a7c62e23ac856c2fa94')

build() {
  cd "${srcdir}/${pkgname}-src-${pkgver}-beta"
  patch -p0 -i "${srcdir}/audacity-1.3.13-ffmpeg.patch"
  WX_CONFIG=/usr/bin/wx-config ./configure --prefix=/usr \
    --with-portaudio --with-libsamplerate \
    --without-libresample --with-libmad \
    --with-ffmpeg --with-id3tag --with-libflac \
    --with-vorbis --with-libexpat \
    --with-libsndfile --with-soundtouch \
    --enable-unicode --without-taglib
  make
}

package() {
  cd "${srcdir}/${pkgname}-src-${pkgver}-beta"
  make DESTDIR="${pkgdir}" install
}