# $Id: PKGBUILD 184361 2013-05-06 19:36:36Z foutrelis $
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
# Maintainer: Gaetan Bisson <bisson@archlinux.org>

pkgname=avahi
pkgver=0.6.31
pkgrel=7
pkgdesc='Multicast/unicast DNS-SD framework'
url='http://www.avahi.org/'
license=('LGPL')
arch=('i686' 'x86_64' 'mips64el')
options=('!libtool' '!emptydirs')
depends=('expat' 'libdaemon' 'glib2' 'libcap' 'gdbm')
optdepends=('dbus: communicating with client applications'
            'gtk3: avahi-discover-standalone, bshell, bssh, bvnc'
            'gtk2: gtk2 bindings'
            'qt3: qt3 bindings'
            'qt4: qt4 bindings'
            'pygtk: avahi-bookmarks, avahi-discover'
            'twisted: avahi-bookmarks')
[ "$CARCH" != "mips64el" ] && optdepends+=('mono: mono bindings')
optdepends+=('dbus-python: avahi-discover'
            'nss-mdns: NSS support for mDNS')
makedepends=('qt3' 'qt4' 'pygtk' 'intltool' 'python2-dbus'
             'gobject-introspection' 'gtk3' 'xmltoman')
[ "$CARCH" != "mips64el" ] && makedepends+=('mono' 'gtk-sharp-2')
backup=('etc/avahi/hosts'
        'etc/avahi/avahi-daemon.conf'
        'etc/avahi/services/ssh.service'
        'etc/avahi/services/sftp-ssh.service'
        'usr/lib/avahi/service-types.db'
        'usr/share/avahi/service-types')
source=("http://www.avahi.org/download/avahi-${pkgver}.tar.gz"
        'rc.d.patch')
sha1sums=('7e05bd78572c9088b03b1207a0ad5aba38490684'
          '625ad7c131c0c1c383caeddef18fc7a32d8f3ab9')

conflicts=('howl' 'mdnsresponder')
provides=('howl' 'mdnsresponder')

install=install

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	sed -i 's/netdev/network/g' avahi-daemon/avahi-dbus.conf
	patch -p1 -i ../rc.d.patch

  [ "$CARCH" = "mips64el" ] && \
    extra="--disable-mono"

	export MOC_QT3=/usr/bin/moc-qt3
	export MOC_QT4=/usr/bin/moc-qt4

	# pygtk requires python2; make it explicit in case other python are installed: FS#21865
	PYTHON=python2 \
	./configure \
		--prefix=/usr \
		--sysconfdir=/etc \
		--localstatedir=/var \
		--disable-static \
		--disable-monodoc \
		--enable-compat-libdns_sd \
		--enable-compat-howl \
		--with-distro=archlinux \
		--with-avahi-priv-access-group=network \
		--with-autoipd-user=avahi \
		--with-autoipd-group=avahi \
        $extra \
		--with-systemdsystemunitdir=/usr/lib/systemd/system \

	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install

	cd "${pkgdir}"
	sed -i '1c #!/usr/bin/python2' usr/bin/avahi-{bookmarks,discover}
	sed -i 's:/sbin/resolvconf:/usr/sbin/resolvconf:g' etc/avahi/avahi-dnsconfd.action

	# howl and mdnsresponder compatability
	(cd usr/include; ln -s avahi-compat-libdns_sd/dns_sd.h dns_sd.h; ln -s avahi-compat-howl howl)
	(cd usr/lib/pkgconfig; ln -s avahi-compat-howl.pc howl.pc)
}