# $Id: PKGBUILD 141668 2011-11-02 03:17:12Z eric $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: György Balló <ballogy@freestart.hu>

pkgname=banshee
pkgver=2.4.1
pkgrel=1
pkgdesc="Music management and playback for GNOME"
arch=('i686' 'x86_64' 'mips64el')
url="http://banshee.fm/"
license=('MIT')
depends=(libxxf86vm gstreamer0.10-base-plugins mono-addins dbus-sharp-glib boo libwebkit libsoup-gnome gdata-sharp taglib-sharp gudev-sharp gkeyfile-sharp gconf-sharp libmtp libgpod mono-zeroconf desktop-file-utils hicolor-icon-theme xdg-utils media-player-info gstreamer0.10-bad-plugins mono-upnp)
makedepends=('intltool' 'gnome-doc-utils' 'gtk-sharp-beans')
optdepends=('gstreamer0.10-good-plugins: Extra media codecs'
            'gstreamer0.10-ugly-plugins: Extra media codecs'
            'gstreamer0.10-ffmpeg: Extra media codecs'
            'brasero: CD burning')
options=('!libtool')
install=$pkgname.install
source=(http://download.gnome.org/sources/$pkgname/2.4/$pkgname-$pkgver.tar.xz
        banshee-recent-gpod.patch)
md5sums=('18d77594e524ff5e51c5cca5c6b31a34'
         'e988bb83e1a49e5f0da5958e8af6508e')

build() {
  export MONO_SHARED_DIR="$srcdir/.wabi"
  mkdir -p "$MONO_SHARED_DIR"

  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i "$srcdir/banshee-recent-gpod.patch"
  
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --disable-docs \
              --disable-static \
              --disable-scrollkeeper \
              --disable-schemas-install \
              --with-vendor-build-id=ArchLinux
  make
}

package() {
  export MONO_SHARED_DIR="$srcdir/.wabi"
  mkdir -p "$MONO_SHARED_DIR"

  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -D -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}