# $Id: PKGBUILD 170864 2012-11-12 20:12:13Z heftig $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Adam Hani Schakaki <krzd@krzd.net>

pkgname=caribou
pkgver=0.4.4.2
pkgrel=1
pkgdesc="A text entry and UI navigation application being developed as an alternative to the Gnome On-screen Keyboard."
arch=('i686' 'x86_64' 'mips64el')
url="http://live.gnome.org/Caribou"
license=('LGPL')
depends=('at-spi2-atk' 'pyatspi' 'python2-gobject' 'gtk3' 'libxklavier' 'libgee' 'clutter' 'dconf')
makedepends=('intltool' 'docbook-xsl')
install=caribou.install
options=(!libtool !emptydirs)
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/0.4/$pkgname-$pkgver.tar.xz)
sha256sums=('22fba681b3e6041494ac4fa41b8286957bade0cc6158c110fe8f3c980af6913d')

build() {
  cd $pkgname-$pkgver
  sed -i s'|#!/usr/bin/python|#!/usr/bin/python2|'g tools/{fix_gir,make_schema}.py
  export PYTHON=/usr/bin/python2
  ./configure --prefix=/usr --sysconfdir=/etc \
    --libexecdir=/usr/lib/caribou \
    --disable-gtk2-module \
    --disable-static \
    --disable-schemas-compile
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: