# $Id: PKGBUILD 154935 2012-03-31 09:53:13Z ronald $
# Maintainer: Juergen Hoetzel <juergen@archlinux.org>
pkgname=clisp
pkgver=2.49
pkgrel=3.1
pkgdesc="ANSI Common Lisp interpreter, compiler and debugger"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://clisp.cons.org/"
depends=('readline' 'libsigsegv')
provides=('common-lisp')
makedepends=('ffcall')
options=('!makeflags' '!emptydirs')
source=("http://downloads.sourceforge.net/sourceforge/clisp/clisp-${pkgver}.tar.bz2")
md5sums=('1962b99d5e530390ec3829236d168649')

build() {
  cd $srcdir/${pkgname}-${pkgver}
  ./configure --prefix=/usr --with-readline --with-ffcall src
  cd src
  ./makemake --prefix=/usr --with-readline --with-ffcall --with-dynamic-ffi > Makefile
  # Dirty hack for using arimips64 instead of arimips.c
  [ $CARCH = "mips64el" ] && ln -s arimips64.c arimips.c
  make
  sed -i 's,http://www.lisp.org/HyperSpec/,http://www.lispworks.com/reference/HyperSpec/,g' config.lisp
  make
}

check() {
  cd $srcdir/${pkgname}-${pkgver}/src
  make check
}

package() {
  cd $srcdir/${pkgname}-${pkgver}/src
  make DESTDIR=$pkgdir install
}