# $Id: PKGBUILD 143665 2011-11-28 09:23:06Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=cln
pkgver=1.3.2
pkgrel=1.2
pkgdesc="Class library for numbers"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.ginac.de/CLN/"
license=('GPL')
[[ "${CARCH}" == 'mips64el' ]] || depends=('gmp')
makedepends=('texlive-core')
options=('!libtool')
install=cln.install
source=(http://www.ginac.de/CLN/${pkgname}-${pkgver}.tar.bz2)
md5sums=('d897cce94d9c34d106575ed4ec865d71')
sha1sums=('c30dca80e75f45e2107f233075e6d0339ea884b0')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i 's/<sizeof(mp_limb_t) > sizeof(long)>/<(sizeof(mp_limb_t) > sizeof(long))>/' configure
  # For unknown reasons it fails.
  if [[ "${CARCH}" == 'mips64el' ]] ; then
      use_gmp=--without-gmp
  else
      use_gmp=
  fi
  ./configure --prefix=/usr $use_gmp
  make all html pdf
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make check
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install install-html install-pdf
}