# $Id: PKGBUILD 175737 2013-01-20 22:18:44Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>

pkgbase=doxygen
pkgname=('doxygen' 'doxygen-docs')
pkgver=1.8.3.1
pkgrel=1
license=('GPL')
arch=(i686 x86_64 'mips64el')
url="http://www.doxygen.org/"
makedepends=('gcc-libs' 'flex' 'qt' 'texlive-core' 'ghostscript'
             'texlive-latexextra' 'graphviz')
source=(http://ftp.stack.nl/pub/users/dimitri/${pkgname}-${pkgver}.src.tar.gz)
md5sums=('31b0aaab51c5cab7db9f0ebbe9f85530')
sha1sums=('289fc809f44b8025d45279deefbaee7680efd88f')

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"
  QTDIR=/usr ./configure --prefix /usr --with-doxywizard
  make
}

package_doxygen() {
  pkgdesc="A documentation system for C++, C, Java, IDL and PHP"
  depends=('gcc-libs')
  optdepends=('graphviz: for caller/callee graph generation'
              'qt: for doxywizard')

  cd "${srcdir}/${pkgbase}-${pkgver}"
  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install
}

package_doxygen-docs() {
  pkgdesc="Developer documentation for doxygen"

  cd "${srcdir}/${pkgbase}-${pkgver}"

  # Needs fonts removed from our TeXLive.
  sed -i -e 's;$(MAKE) -C latex;:;' \
      -e 's;$(INSTTOOL) -m 644 latex/doxygen_manual.pdf $(DESTDIR)/$(DOCDIR);:;' \
      Makefile

  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install_docs
}
md5sums=('54245ba38a30f50fd7ae6e62fc05de15')
sha1sums=('e74240f445e08b782fa7a3de5f0b333901307587')