# $Id: PKGBUILD 162028 2012-06-19 01:01:27Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>

pkgbase=doxygen
pkgname=('doxygen' 'doxygen-docs')
pkgver=1.8.1.1
pkgrel=1
license=('GPL')
arch=(i686 x86_64 'mips64el')
url="http://www.doxygen.org/"
makedepends=('gcc-libs' 'flex' 'qt' 'texlive-core' 'ghostscript' 'texlive-latexextra')
source=(ftp://ftp.stack.nl/pub/users/dimitri/${pkgname}-${pkgver}.src.tar.gz)
md5sums=('a08c43c5675f79e0787e700c2d39ee33')
sha1sums=('51184af9f27d6572826581de0da5b6b044e34d94')

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"
  QTDIR=/usr ./configure --prefix /usr --with-doxywizard
  make
}

package_doxygen() {
  pkgdesc="A documentation system for C++, C, Java, IDL and PHP"
  depends=('gcc-libs')
  optdepends=('graphviz: for caller/callee graph generation'
              'qt: for doxywizard')

  cd "${srcdir}/${pkgbase}-${pkgver}"
  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install
}

package_doxygen-docs() {
  pkgdesc="Developer documentation for doxygen"

  cd "${srcdir}/${pkgbase}-${pkgver}"

  # Needs fonts removed from our TeXLive.
  sed -i -e 's;$(MAKE) -C latex;:;' \
      -e 's;$(INSTTOOL) -m 644 latex/doxygen_manual.pdf $(DESTDIR)/$(DOCDIR);:;' \
      Makefile

  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install_docs
}