# $Id: PKGBUILD 117080 2011-03-28 14:57:03Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>

pkgbase=doxygen
pkgname=('doxygen' 'doxygen-docs')
pkgver=1.7.4
pkgrel=1
license=('GPL')
arch=(i686 x86_64 'mips64el')
url="http://www.doxygen.org/"
makedepends=('flex' 'texlive-core' 'ghostscript' 'texlive-latexextra') #'qt' 
source=(ftp://ftp.stack.nl/pub/users/dimitri/${pkgname}-${pkgver}.src.tar.gz)
md5sums=('ff908759ff7cd9464424b04ae6c68e48')
sha1sums=('4f68b655c93265cb15ef1b8c9ca35ebc39698cf0')

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"
# mips64el doesn't have qt yet
  [ "$CARCH" != "mips64el" ] && ./configure --prefix /usr --with-doxywizard #QTDIR=/usr 
  [ "$CARCH" = "mips64el" ] && ./configure --prefix /usr
  make
}

package_doxygen() {
  pkgdesc="A documentation system for C++, C, Java, IDL and PHP"
  depends=('gcc-libs')
  [ "$CARCH" = "mips64el" ] || \
  optdepends=('graphviz: for caller/callee graph generation'
              'qt: for doxywizard')

  cd "${srcdir}/${pkgbase}-${pkgver}"
  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install
}

package_doxygen-docs() {
  pkgdesc="Developer documentation for doxygen"

  cd "${srcdir}/${pkgbase}-${pkgver}"
  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install_docs
}