# $Id: PKGBUILD 124886 2011-05-24 21:41:31Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=eog
pkgver=3.0.2
pkgrel=1
pkgdesc="Eye of Gnome: An image viewing and cataloging program"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gnome-desktop' 'libexif' 'lcms' 'desktop-file-utils' 'exempi'
         'dbus-glib' 'libpeas' 'librsvg' 'gnome-icon-theme' 'dconf')
makedepends=('gtk-doc' 'intltool')
install=eog.install
groups=('gnome-extra')
options=('!emptydirs' '!libtool')
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('96fa5af97baba0bce8dec376d7cd49512768505f473b11b2cf61881f6be8cb60')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-scrollkeeper
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  # remove it from Xfce menu that ships its own thingy
  echo "NotShowIn=XFCE" >> ${pkgdir}/usr/share/applications/eog.desktop
}