# $Id: PKGBUILD 125696 2011-05-28 10:41:59Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=epiphany
pkgver=3.0.2
pkgrel=2
install=epiphany.install
pkgdesc="A GNOME3 web browser based on the WebKit rendering engine."
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
depends=('libsoup-gnome' 'gsettings-desktop-schemas' 'libwebkit3' 'nss'
         'iso-codes' 'dconf' 'gobject-introspection' 'desktop-file-utils'
         'hicolor-icon-theme' 'seed')
makedepends=('intltool' 'networkmanager' 'gnome-doc-utils' 'startup-notification')
options=('!libtool' '!emptydirs')
groups=('gnome')
url="http://www.gnome.org/projects/epiphany/"
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('befcc9b6061b2e5e9c78399423b09e27dc301dec55d96bf63590d543ce9bb805')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var \
      --disable-scrollkeeper \
      --enable-network-manager \
      --enable-seed
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}