# $Id: PKGBUILD 111648 2011-02-28 00:45:15Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=fluxbox
pkgver=1.3.1
pkgrel=1
pkgdesc="A lightweight and highly-configurable window manager"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.fluxbox.org"
license=('MIT')
depends=('libxft' 'libxpm' 'libxinerama' 'libxrandr' 'gcc-libs' 'sh' 'imlib2' 'fribidi')
makedepends=('pkg-config')
optdepends=('xorg-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
options=('!makeflags')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.bz2 \
        fluxbox.desktop)
md5sums=('0eaa940a69c0a876a520bb85d67b8bec' 'eeae9c88a2526ac0bd8afcd9ce97f9ed')
sha1sums=('1c4755b8ac1042c98f700848240ac99ef18dca01' 'f3f83b8ce84d79c2f8670ef687e0dd89ab0552b8')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
    --enable-gnome --enable-xft --enable-xinerama \
    --enable-imlib2 --enable-nls
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m644 ../fluxbox.desktop "${pkgdir}/usr/share/xsessions/fluxbox.desktop"
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}