# $Id: PKGBUILD 168622 2012-10-13 15:13:40Z andyrtr $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=freeglut
pkgver=2.8.0
pkgrel=2
pkgdesc="Provides functionality for small OpenGL programs"
arch=('i686' 'x86_64' 'mips64el')
url="http://freeglut.sourceforge.net/"
license=('MIT')
depends=('libxi' 'libxrandr' 'libgl')
makedepends=('mesa' 'glu' 'libxxf86vm')
replaces=('glut')
provides=('glut')
conflicts=('glut')
options=('!libtool')
source=(http://downloads.sourceforge.net/freeglut/${pkgname}-${pkgver}.tar.gz)
md5sums=('5db8651af306bc403fbfd36934a20e1d')
sha1sums=('4debbe559c6c9841ce1abaddc9d461d17c6083b1')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # smooth_opengl3 demo doesn't build with recent mesa, Gentoo bug #428382
  sed -i "s/smooth_opengl3 //" progs/demos/Makefile.*

  autoreconf -vfi  
  ./configure --prefix=/usr --disable-static
  make all
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}