# $Id: PKGBUILD 201340 2013-12-09 07:41:57Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=freetype2
pkgver=2.5.2
pkgrel=1
pkgdesc="TrueType font rendering library"
arch=(i686 x86_64 'mips64el')
license=('GPL')
url="http://freetype.sourceforge.net"
depends=('zlib' 'bzip2' 'sh' 'libpng')
source=(http://downloads.sourceforge.net/sourceforge/freetype/freetype-${pkgver}.tar.bz2
        freetype-2.2.1-enable-valid.patch
        freetype-2.5.1-enable-spr.patch
        freetype-2.5.1-enable-sph.patch)
md5sums=('10e8f4d6a019b124088d18bc26123a25'
         '214119610444c9b02766ccee5e220680'
         '80a14cce234f3f190cd936ca9060c398'
         '0636ba2ff074201e2ea5c47ac408bc63')

prepare() {
  cd "${srcdir}/freetype-${pkgver}"
  patch -Np1 -i "${srcdir}/freetype-2.2.1-enable-valid.patch"
  patch -Np1 -i "${srcdir}/freetype-2.5.1-enable-spr.patch"

  # Disabled for now due to resistance
  # Kept here for easier rebuilds via ABS
  # https://bugs.archlinux.org/task/35274
  #patch -Np1 -i "${srcdir}/freetype-2.5.1-enable-sph.patch"
}

build() {
  cd "${srcdir}/freetype-${pkgver}"

  ./configure --prefix=/usr --disable-static

  make
}

check() {
  cd "${srcdir}/freetype-${pkgver}"
  make -k check
}

package() {
  cd "${srcdir}/freetype-${pkgver}"
  make DESTDIR="${pkgdir}" install
}