# $Id: PKGBUILD 151400 2012-02-26 10:21:51Z pierre $
# Maintainer: Daniel Isenmann <daniel [at] archlinux.org>
# Contributor: dorphell <dorphell@gmx.net>

pkgname=gc
pkgver=7.2alpha6
pkgrel=1
pkgdesc="A garbage collector for C and C++"
arch=(i686 x86_64 'mips64el')
url="http://www.hpl.hp.com/personal/Hans_Boehm/gc/"
license=('GPL')
source=("http://www.hpl.hp.com/personal/Hans_Boehm/gc/gc_source/${pkgname}-${pkgver}.tar.gz")
depends=('gcc-libs')
options=(!libtool)
md5sums=('319d0b18cc4eb735c8038ece9df055e4')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  # Installing a single file twice fails.
  sed -ri 's/(am__append_6 =) .*$/\1/' Makefile.in
  ./configure --prefix=/usr --enable-cplusplus
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}/usr/share/gc"
  install -m755 -d "${pkgdir}/usr/share/doc/gc"
  install -m644 doc/README{,.{changes,contributors,environment,linux}} \
    "${pkgdir}/usr/share/doc/gc/"

  sed -i -e 's/GC_MALLOC 1L/gc 3/' doc/gc.man
  install -m755 -d "${pkgdir}/usr/share/man/man3"
  install -m644 doc/gc.man "${pkgdir}/usr/share/man/man3/gc.3"
}