# $Id: PKGBUILD 125557 2011-05-26 17:02:09Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gedit
pkgver=3.0.3
pkgrel=2
pkgdesc="A text editor for GNOME"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
depends=('gtksourceview3' 'gsettings-desktop-schemas' 'libpeas' 'enchant' 'iso-codes' 'libsm' 'desktop-file-utils' 'pygobject' 'dconf')
makedepends=('gnome-doc-utils' 'intltool')
groups=('gnome-extra')
options=('!libtool' '!emptydirs')
url="http://www.gnome.org"
install=gedit.install
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('16764f0cf17fcd85f9c3f031bb151aa87ef1e727e8d19814a4746d376adca578')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
      --sysconfdir=/etc --localstatedir=/var \
      --libexecdir=/usr/lib --disable-scrollkeeper \
      --disable-updater --disable-schemas-compile \
      --enable-python
  make
}

package(){
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}