# $Id: PKGBUILD 171320 2012-11-17 07:46:20Z eric $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: bzklrm <bzklrm@gmail.com>
# Additional contributors Senjin, Xavier, dundee

pkgname=glpk
pkgver=4.47
pkgrel=2
pkgdesc="GNU Linear Programming Kit : solve LP, MIP and other problems."
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnu.org/software/glpk/glpk.html"
license=('GPL')
depends=('glibc')
options=('!libtool')
source=(http://ftp.gnu.org/gnu/glpk/${pkgname}-${pkgver}.tar.gz{,.sig})
sha1sums=('35e16d3167389b6bc75eb51b4b48590db59f789c'
          'e29069fb4e8e34929a980a8659b3dd7ccd92a676')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr

  if [ "$CARCH" != "i686" ]; then
    make CFLAGS="$CFLAGS -fPIC"  
  else
    make
  fi
}

package(){
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 doc/glpk.pdf "${pkgdir}/usr/share/doc/glpk/glpk.pdf"
  install -Dm644 doc/gmpl.pdf "${pkgdir}/usr/share/doc/glpk/gmpl.pdf"
}