# $Id: PKGBUILD 196390 2013-10-12 16:54:13Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-chess
pkgver=3.10.1
pkgrel=1
pkgdesc="Play the classic two-player boardgame of chess"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
depends=('desktop-file-utils' 'hicolor-icon-theme' 'gtk3' 'librsvg' 'sqlite')
makedepends=('intltool' 'itstool' 'gobject-introspection')
optdepends=('gnuchess: Play against computer')
conflicts=('gnome-games')
replaces=('gnome-games')
options=('!emptydirs' '!libtool')
install=gnome-chess.install
url="https://live.gnome.org/Chess"
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('6541db85d2ca5b843fce61bd3be9c08733cf456c6fdf9bbc02ad78d043ca71fd')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --disable-schemas-compile
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}