# $Id: PKGBUILD 117742 2011-04-04 17:38:36Z heftig $
# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>

pkgname=gnome-color-manager
pkgver=3.0.0
pkgrel=1
pkgdesc="Color profile manager for the GNOME desktop"
arch=(i686 x86_64)
url="http://projects.gnome.org/gnome-color-manager/"
license=(GPL2)
depends=(lcms2 gnome-settings-daemon gnome-control-center vte3 sane exiv2
         hicolor-icon-theme desktop-file-utils)
makedepends=(intltool gtk-doc)
install=gnome-color-manager.install
options=('!libtool')
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
sha256sums=('9e030b2a5dd61010bce25c2e3cdfca6e7ab3954fecb74dbf88f6a8e2c70b7207')

build(){
  cd "$srcdir/$pkgname-$pkgver"

  # man pages need docbook-sgml, which we don't have
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib --disable-static --disable-man-pages

  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}