# $Id: PKGBUILD 117756 2011-04-04 17:41:50Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-power-manager
pkgver=3.0.0
pkgrel=1
pkgdesc="Session daemon that makes it easy to manage your laptop or desktop system."
arch=(i686 x86_64 'mips64el')
url="http://www.gnome.org/projects/gnome-power-manager/"
license=('GPL')
depends=('libnotify' 'gconf' 'libcanberra' 'gnome-icon-theme' 'upower'
         'libgnome-keyring' 'dconf')
makedepends=('intltool' 'gnome-doc-utils' 'gnome-control-center')
options=(!emptydirs)
install=gnome-power-manager.install
groups=(gnome-extra)
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('20d8c147a50eef534e81edb033648e5e9cf7a3f733e80c5d6c946b571f7ae4e1')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var \
      --libexecdir=/usr/lib/gnome-power-manager \
      --disable-scrollkeeper \
      --with-dbus-services=/usr/share/dbus-1/services \
      --disable-schemas-compile
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}