# $Id: PKGBUILD 158752 2012-05-09 07:43:11Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>

pkgname=gtkhtml4
_pkgbasename=gtkhtml
pkgver=4.4.1
pkgrel=2
pkgdesc="A lightweight HTML renderer/editor widget for GTK3"
arch=(i686 x86_64)
license=('GPL')
depends=('gtk3' 'enchant' 'iso-codes' 'gnome-icon-theme' 'libsoup')
makedepends=('intltool')
url="http://www.gnome.org"
options=('!libtool')
source=(http://ftp.gnome.org/pub/gnome/sources/$_pkgbasename/${pkgver%.*}/$_pkgbasename-$pkgver.tar.xz
        fix-selection-behaviour-in-iframe.patch)
sha256sums=('2fb3286c5ab8b6349a694156f803e1162c5a234d30548eb0afdf82e139923236'
            'ed1d9a4515f9137aaa94511f421b610af04091c56573ff9b74ba104a2ca1b207')

build() {
    cd "$_pkgbasename-$pkgver"
    patch -Np1 -i "${srcdir}/fix-selection-behaviour-in-iframe.patch"
    ./configure --prefix=/usr --sysconfdir=/etc \
        --libexecdir=/usr/lib/gtkhtml4 \
        --localstatedir=/var --disable-static
    make
}

package() {
    cd "$_pkgbasename-$pkgver"
    make DESTDIR="$pkgdir" install
}