# $Id: PKGBUILD 198707 2013-11-02 08:25:46Z ioni $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: sh0 <mee@sh0.org>

pkgname=iptraf-ng
pkgver=1.1.4
pkgrel=1
pkgdesc="A console-based network monitoring utility (a fork of original iptraf)"
url="https://fedorahosted.org/iptraf-ng/"
arch=('i686' 'x86_64' 'mips64el')
depends=('ncurses')
license=('GPL2')
replaces=('iptraf')
source=(https://fedorahosted.org/releases/i/p/$pkgname/$pkgname-$pkgver.tar.gz
        0001-token-ring-kernel-v3.5-kill-off-token-ring-support.patch
        iptraf-ng-linux-3.5-compat.patch)
md5sums=('de27cfeeede96e2acfb0edc8439b034a'
         'd5eab1e094b93f0e3a256cf9ccfaa9c3'
         'd2ddee5f9ff485155235f7cb4671d8fb')

prepare() {
  cd "$pkgname-$pkgver"
  patch -p1 -i ${srcdir}/0001-token-ring-kernel-v3.5-kill-off-token-ring-support.patch
  patch -p1 -i ${srcdir}/iptraf-ng-linux-3.5-compat.patch
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --sbindir=/usr/bin
  make CFLAGS="$CFLAGS -std=gnu99"
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR=$pkgdir install
}