# $Id: PKGBUILD 169946 2012-10-30 22:46:25Z heftig $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=kdebase-workspace
_pkgname=kde-workspace
pkgver=4.9.2
pkgrel=5
pkgdesc="Provides the interface and basic tools for the KDE workspace"
arch=('i686' 'x86_64' 'mips64el')
url='https://projects.kde.org/projects/kde/kde-workspace'
license=('GPL' 'LGPL' 'FDL')
groups=('kde')
# note on libxdamage:
# 	not detected by namcap because libgl depends on it
#	but nvidia providing libgl does not depend on libxdamage
depends=('kdepim-runtime' 'lm_sensors' 'libraw1394' 'libqalculate'
         'qimageblitz' 'polkit-kde' 'xorg-xprop' 'libxdamage'
         'libxklavier' 'xorg-xsetroot' 'libxcomposite' 'libxinerama'
         'xorg-xrdb' 'libgles' 'libegl' 'libxres' 'xorg-xrandr'
         'xorg-xmessage' 'libusb-compat' 'kde-base-artwork')
makedepends=('cmake' 'automoc4' 'boost' 'kdebindings-python2' 'networkmanager' 'mesa')
optdepends=('kde-wallpapers: wallpapers for KDE Plasma Workspaces')
install="${pkgname}.install"
backup=('usr/share/config/kdm/kdmrc')
source=("http://download.kde.org/stable/${pkgver}/src/${_pkgname}-${pkgver}.tar.xz"
        'kdm' 'kde.pam' 'kde-np.pam' 'kscreensaver.pam' 'kdm.service' 'kdm.logrotate'
        'etc-scripts.patch' 'terminate-server.patch' 'kdm-xinitrd.patch'
        'logind-support.patch')
sha1sums=('091bec159d85db2a9a6d6b1b43a53183c23de488'
          '5db3a245201bd4a50e65aa2ef583cf5490e4f646'
          '660eae40a707d2711d8d7f32a93214865506b795'
          'b7980f2e199963caf8e92b499042d244ece2fca0'
          '106635aa1aae51d6f0668b1853f6c49a4fe9d3d8'
          'b6f8e8692737b11eec1f8022ce74b5b23e247b1b'
          'bbe55f2000217474ce7246f12ee437ceaaf7e9ae'
          'c079ebd157c836ba996190f0d2bcea1a7828d02c'
          'ac7bc292c865bc1ab8c02e6341aa7aeaf1a3eeee'
          'd509dac592bd8b310df27991b208c95b6d907514'
          'ccde71c42e19feaf40d3bd76e7396a0cb6df012f')

build() {
	cd ${_pkgname}-${pkgver}

    # reads the shell scripts in /etc/kde/
    patch -p0 -i "${srcdir}"/etc-scripts.patch
    # FS#26120
	patch -p1 -i "${srcdir}"/kdm-xinitrd.patch

    # KDEBUG#202629
	patch -p0 -i "${srcdir}"/terminate-server.patch
    # KDEBUG#307412 (fixed upstream)
    patch -p1 -i "${srcdir}"/logind-support.patch

    cd ../

	mkdir build
	cd build
	cmake ../${_pkgname}-${pkgver} \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_SKIP_RPATH=ON \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DWITH_Xmms=OFF \
        -DWITH_Googlegadgets=OFF \
        -DWITH_libgps=OFF \
        -DPYTHON_EXECUTABLE=/usr/bin/python2 \
        -DWITH_CkConnector=OFF
	make
}

package() {
	cd build
	make DESTDIR="${pkgdir}" install

	install -D -m644 "${srcdir}"/kde.pam "${pkgdir}"/etc/pam.d/kde
	install -D -m644 "${srcdir}"/kde-np.pam "${pkgdir}"/etc/pam.d/kde-np
	install -D -m644 "${srcdir}"/kscreensaver.pam "${pkgdir}"/etc/pam.d/kscreensaver

	install -d -m755 "${pkgdir}"/usr/share/xsessions/
	ln -sf /usr/share/apps/kdm/sessions/kde-plasma{,-safe}.desktop \
      "${pkgdir}"/usr/share/xsessions/
	install -d -m755 "${pkgdir}"/etc/kde/{env,shutdown}

	install -d -g 135 -o 135 "${pkgdir}"/var/lib/kdm
    install -D -m755 "${srcdir}"/kdm "${pkgdir}"/etc/rc.d/kdm
    install -D -m644 "${srcdir}"/kdm.service \
      "${pkgdir}"/usr/lib/systemd/system/kdm.service
    install -Dm644 "${srcdir}"/kdm.logrotate "${pkgdir}"/etc/logrotate.d/kdm
}