# $Id: PKGBUILD 139908 2011-10-05 19:09:32Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgbase=kdesdk-kate
pkgname=('kdebase-kwrite'
         'kdesdk-kate')
pkgver=4.7.2
pkgrel=1
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
makedepends=('kdelibs ''cmake' 'automoc4')
source=("http://download.kde.org/stable/${pkgver}/src/kate-${pkgver}.tar.bz2"
        'pkgbuild-syntax-highlight.patch')
sha1sums=('467b0558f1f86d0b210abd2d78c94cbe63b8579d'
          'ab0c5d2a796b0f283154799add161c99f48ffcd5')

build() {
  cd "${srcdir}"/kate-${pkgver}
  patch -p1 -i "${srcdir}"/pkgbuild-syntax-highlight.patch

  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../kate-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_KTEXTEDITOR=OFF
  make
}

package_kdebase-kwrite() {
  pkgdesc="Text Editor"
  depends=('kdebase-runtime')
  groups=('kde' 'kdebase')
  install='kdebase-kwrite.install'

  cd "${srcdir}"/build/kwrite
  make DESTDIR="${pkgdir}" install

  cd "${srcdir}"/build/part
  make DESTDIR="${pkgdir}" install

  cd "${srcdir}"/build/doc/kwrite
  make DESTDIR="${pkgdir}" install
}

package_kdesdk-kate() {
  pkgdesc="Advanced Text Editor"
  depends=('kdebase-kwrite')
  groups=('kde' 'kdesdk')
  install='kdesdk-kate.install'

  cd "${srcdir}"/build/kate
  make DESTDIR="${pkgdir}" install

  cd "${srcdir}"/build/doc/kate
  make DESTDIR="${pkgdir}" install
}